TMS iCL High performance native iOS look & feel components for Delphi FireMonkey

FMX

TMS iCL

High performance native iOS look & feel components for Delphi FireMonkey

v4.0.0.1
Features
Help
Downloads
Buy

Tips and Frequently Asked Questions

Supported Platforms and Operating Systems

The following table shows supported platforms and operating systems for different RAD Studio versions:
http://docwiki.embarcadero.com/PlatformStatus/en/Main_Page

Adding an UIToolBarItem to the toolbar of an UITableView in iCL

The TTMSFMXNativeUITableView has a toolbar property that can be set to True. When adding an item, you can then add it to the TableViewController instead of the NavigationController. Below is the source code that demonstrates this.

unit UDemo;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, iOSApi.Foundation,
  FMX.TMSNativeUIBaseControl, FMX.TMSNativeUIView, FMX.TMSNativeUICore,
  FMX.TMSNativeUIViewController, FMX.TMSNativeUINavigationController, FMX.TMSNativeUIToolBar,
  MacApi.ObjectiveC, TypInfo, MacApi.ObjcRuntime, FMX.TMSNativeUITableView;

type
  IUIToolBarButtonEventHandler = interface(NSObject)
  ['{1ACF3DFA-A90B-4F06-ACF1-8A40076BC9ED}']
    procedure Click(Sender: Pointer); cdecl;
  end;

  TUIToolBarButtonEventHandler = class(TOCLocal)
  protected
    function GetObjectiveCClass: PTypeInfo; override;
  public
    procedure Click(Sender: Pointer); cdecl;
  end;

  TDemoForm = class(TForm)
    TMSFMXNativeUITableView1: TTMSFMXNativeUITableView;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
    FEventHandler: TUIToolBarButtonEventHandler;
    FHideButton: UIBarButtonItem;
  public
    { Public declarations }
  end;

var
  DemoForm: TDemoForm;

implementation

{$R *.fmx}

procedure TDemoForm.FormCreate(Sender: TObject);
begin
  FEventHandler := TUIToolBarButtonEventHandler.Create;
  FHideButton := TUIBarButtonItem.Wrap(TUIBarButtonItem.Wrap(TUIBarButtonItem.OCClass.alloc).initWithBarButtonSystemItem(integer(siBarButtonSystemItemAdd),
    FEventHandler.GetObjectID, sel_getUid('Click:')));

  TMSFMXNativeUITableView1.Options.ToolBar := True;
  TMSFMXNativeUITableView1.TableViewController.navigationItem.setRightBarButtonItem(FHideButton);
end;

{ TUIToolBarButtonEventHandler }

procedure TUIToolBarButtonEventHandler.Click(Sender: Pointer);
begin
  ShowMessage('clicked');
end;

function TUIToolBarButtonEventHandler.GetObjectiveCClass: PTypeInfo;
begin
  Result := TypeInfo(IUIToolBarButtonEventHandler);
end;

end.

Fixing the FMX TWebBrowser issue on iOS 9

http://tmssoftware.com/site/blog.asp?post=317

How to verify if TouchID is available on the device

As soon as you add the LocalAuthentication component, you are bound to iOS 8.0. The component already internally checks if authentication is possible before executing it. There is currently no separate verification but if you want to verify if TouchID is available you can use the following code (it requires the FMX.TMSNativeUICore unit)

function TForm1.TouchIDAvailable: Boolean;
var
  ctx: LAContext;
  error: PPointer;
  auth: NativeInt;
begin
  result := False;
  ctx := TLAContext.Wrap(TLAContext.Wrap(TLAContext.OCClass.alloc).init);
  error := nil;
  auth := LAPolicyDeviceOwnerAuthenticationWithBiometrics;
  if ctx.canEvaluatePolicy(auth, error) then
    Result := True;
  ctx.release;
end;

Initializing controls on multiple forms

When creating an application that manages multiple forms, only the mainform will initialize and display its controls. In this example, the mainform contains an UINavigationController and pushes a UIViewController in view that is placed on a secondary form. Executing the following code, will navigate to the viewcontroller, but the viewcontroller and its children will not be visible / initialized.

TMSFMXNativeUINavigationController1.PushViewController(Form3.TMSFMXNativeUIViewController1,true);

To overcome this, you need to initialize the controls manually by implementing a recursive method InitializeControl:

procedure TForm1.InitializeControl(AControl: TControl);
var
  I: Integer;
begin
  if not Assigned(AControl) then
    Exit;

  if AControl is TTMSFMXNativeUIBaseControl then
  begin
    (AControl as TTMSFMXNativeUIBaseControl).Initialize;
    for I := 0 to AControl.ControlsCount - 1 do
      InitializeControl(AControl.Controls[I]);
  end;
end;

And call the method whenever you need to show a native TMS iCL control that is placed on a form other than the mainform.

procedure TForm1.TMSFMXNativeUIButton1Click(Sender: TObject);
begin
  InitializeControl(SecondaryForm.TMSFMXNativeUIViewController1);
  TMSFMXNativeUINavigationController1.PushViewController(SecondaryForm.TMSFMXNativeUIViewController1,true);
end;

Printing a PDF File

To print a pdf file from iOS, you can use the following code to access the UIPrintInteractionController (it requires MacApi.ObjectiveC, iOSApi.UIKit and iOSApi.Foundation units)

type
  TUIPrintInteractionControllerCompletionHandler = procedure(printInteractionController: Pointer; 
    completed: Pointer; error: Pointer) of object;

  UIPrintInteractionControllerClass = interface(NSObjectClass)
    ['{D3566B82-3014-40C6-B7E3-DFC22AF39319}']
    {class} function canPrintData(data: NSData): Boolean; cdecl;
    {class} function canPrintURL(url: NSURL): Boolean; cdecl;
    {class} function isPrintingAvailable: Boolean; cdecl;
    {class} function printableUTIs: NSSet; cdecl;
    {class} function sharedPrintController: Pointer; cdecl;
  end;
  UIPrintInteractionController = interface(NSObject)
    ['{0FEF6AA7-132B-41C8-BB12-045C43027D4B}']
    function delegate: Pointer; cdecl;
    procedure dismissAnimated(animated: Boolean); cdecl;
    function printFormatter: UIPrintFormatter; cdecl;
    function printInfo: UIPrintInfo; cdecl;
    function printPageRenderer: UIPrintPageRenderer; cdecl;
    function printPaper: UIPrintPaper; cdecl;
    function printingItem: Pointer; cdecl;
    function printingItems: NSArray; cdecl;
    procedure setDelegate(delegate: Pointer); cdecl;
    procedure setPrintFormatter(printFormatter: UIPrintFormatter); cdecl;
    procedure setPrintInfo(printInfo: UIPrintInfo); cdecl;
    procedure setPrintPageRenderer(printPageRenderer: UIPrintPageRenderer); cdecl;
    procedure setPrintingItem(printingItem: Pointer); cdecl;
    procedure setPrintingItems(printingItems: NSArray); cdecl;
    procedure setShowsPageRange(showsPageRange: Boolean); cdecl;
    procedure presentAnimated(animated: Boolean; completionHandler: 
      TUIPrintInteractionControllerCompletionHandler); cdecl;
    function showsPageRange: Boolean; cdecl;
  end;
  TUIPrintInteractionController = class(TOCGenericImport<UIPrintInteractionControllerClass, 
    UIPrintInteractionController>)  end;

var
  pi: UIPrintInfo;
  pic: UIPrintInteractionController;
  fileURL: Pointer;
begin
  pi := TUIPrintInfo.Wrap(TUIPrintInfo.OCClass.printInfo);
  pi.setOutputType(UIPrintInfoOutputGeneral);
  pi.setJobName(TMSFMXNativeUIWebView1.WebView.request.URL.absoluteString);
  pi.setOrientation(UIPrintInfoOrientationPortrait);
  pi.setDuplex(UIPrintInfoDuplexLongEdge);

  pic := TUIPrintInteractionController.Wrap(TUIPrintInteractionController.OCClass.sharedPrintController);
  pic.setPrintInfo(pi);
  pic.setShowsPageRange(True);

  fileURL := TNSURL.OCClass.fileURLWithPath(NSSTR(ExtractFilePath(ParamStr(0))+'sample.pdf'));
  pic.setPrintingItem(fileURL);
  pic.presentAnimated(True, PrintCompleted); 
end;

Merge multiple PDF documents with TMSFMXNativePDFLib

The code below shows how to input and merge multiple PDF documents to a single PDF document.

var
  input: TStringList;
  output: String;
  I, J: Integer;
begin
  input := TStringList.Create;
  input.Add(ExtractFilePath(ParamStr(0)) + 'Egypt.pdf');
  input.Add(ExtractFilePath(ParamStr(0)) + 'BoraBora.pdf');
  input.Add(ExtractFilePath(ParamStr(0)) + 'London.pdf');

  output := TPath.GetDocumentsPath + '/Merged.pdf';
  TMSFMXNativePDFLib1.BeginDocument(output);
  for I := 0 to input.Count - 1 do
  begin
    TMSFMXNativePDFLib1.OpenDocument(input[I]);
    for J := 1 to TMSFMXNativePDFLib1.GetPageCount do
    begin
      TMSFMXNativePDFLib1.GetPageInfo(J);
      TMSFMXNativePDFLib1.NewPage;
      TMSFMXNativePDFLib1.DrawPage(J);
    end;
    TMSFMXNativePDFLib1.CloseDocument;
  end;
  TMSFMXNativePDFLib1.EndDocument;

  input.Free;
end;

How to style the UITableView

You can style the UITableView as well as other controls. This is demonstrated in the ShowCase application explained at the following page: https://www.tmssoftware.com/site/iosshowcase.asp

Add a custom pin image annotation to the TTMSFMXNativeMKMapView

The following code can be used to show a custom pin image when adding an annotation to the mapview component.
The annotation is added to the center of the Map based on an image that has been added to the root folder in the deployment window.

var
  loc: TTMSFMXNativeMKMapLocation;
  ann: TTMSFMXNativeMKAnnotation;
begin
  TMSFMXNativeMKMapView1.BeginUpdate;
  loc := TMSFMXNativeMKMapView1.XYToCoordinate(TMSFMXNativeMKMapView1.Width / 2, TMSFMXNativeMKMapView1.Height / 2);
  ann := TMSFMXNativeMKMapView1.AddAnnotation(loc, 'Hello', 'World');
  ann.Bitmap.LoadFromFile(ExtractFilePath(ParamStr(0))+'pin.png');
  TMSFMXNativeMKMapView1.EndUpdate;

Printing the contents of an UIWebView

This sample demonstrates how to print the contents of an UIWebView.
https://download.tmssoftware.com/download/UWebViewPrint.zip
It uses the UIPrintInteractionController that looks for a printer with AirPrint support.

Mixing FireMonkey controls and TMS iCL controls

In this article we try to give a technical background of the differences between FireMonkey framework controls and TMS iCL controls. With this background it should be easier to understand the limitations and pitfalls with mixing FireMonkey framework controls and TMS iCL controls: https://www.tmssoftware.com/site/fmxicl.asp

Block Animations

Block animations are built-in the iOS Core Animation framework. To demonstrate this with a sample: The following code sets a native UIView component outside the visible area of an iphone application:

  TMSFMXNativeUIView1.SetBounds(0, 480, 320, 480);

Then from a button click for example, the following code animates the view to be displayed on the new position:

  TUIView.OCClass.beginAnimations(nil, nil);
  TUIView.OCClass.setAnimationDuration(0.4);
  TMSFMXNativeUIView1.SetBounds(0, 0, 320, 480);
  TUIView.OCClass.commitAnimations;

More information on Block animations can be found on the following link: http://developer.apple.com/library/ios/#documentation/windowsviews/conceptual/viewpg_iphoneos/animatingviews/animatingviews.html

Zooming to fit all annotations in MapView

Below is some code that zooms the map to view all annotations that have been added. Add the unit FMX.TMSNativeUICore in the uses list to have access to the MKCoordinateRegion record.

procedure TForm1.ZoomToFit;
var
  maxCoord: TTMSFMXNativeMKMapLocation;
  minCoord: TTMSFMXNativeMKMapLocation;
  coord: TTMSFMXNativeMKMapLocation;
  I: Integer;
  rgnm: MKCoordinateRegion;
begin
  maxCoord.Latitude := -90;
  maxCoord.Longitude := -180;
  minCoord.Latitude := 90;
  minCoord.Longitude := 180;

  for I := 0 to TMSFMXNativeMKMapView1.Annotations.Count - 1 do
  begin
    coord := TMSFMXNativeMKMapView1.Annotations[I].Location;
    if coord.Longitude > maxCoord.Longitude then
      maxCoord.Longitude := coord.Longitude;

    if coord.Latitude > maxCoord.Latitude then
      maxCoord.Latitude := coord.Latitude;

    if coord.Longitude < minCoord.Longitude then
      minCoord.Longitude := coord.Longitude;

    if coord.Latitude < minCoord.Latitude then
      minCoord.Latitude := coord.Latitude;
  end;

  rgnm.center.longitude := (minCoord.Longitude + maxCoord.Longitude) / 2;
  rgnm.center.latitude := (minCoord.Latitude + maxCoord.Latitude) / 2;
  rgnm.span.longitudeDelta := maxCoord.Longitude - minCoord.Longitude;
  rgnm.span.latitudeDelta := maxCoord.Latitude - minCoord.Latitude;

  TMSFMXNativeMKMapView1.MapView.setRegion(rgnm, True);
end;

When deploying to the device, the following error appears: [DCC Error] E2597 ld: file not found: /System/Library/Frameworks/...

Starting from version 1.2 you will get a linker error when compiling your project for an iOS Device target, saying that it does not find the ImageIO framework.

To solve this linker error you will need to add this framework to the SDK Manager. How to do this and solve this issue is explained in the "frameworks" chapter in the documentation:

https://www.tmssoftware.com/site/manuals/tmsicldevguide.pdf

FMX

Buy now

TMS iCL

Single developer license

license for 1 developer
€ 75 yearly renewal * € 125

order now
add to cart

Site license

unlimited developers in the company
€ 235 yearly renewal * € 395

order now
add to cart

Compatibility

Delphi 10.2 Tokyo, 10.3 Rio, 10.4 Sydney, 11 Alexandria (Professional/Enterprise/Architect)

Licensing

Licensing FAQ
License for commercial use: Single developer license, Site license
Includes full source code
Ask questions to our engineers related to purchased product via Support Center
Free 1 year updates and new releases
After 1 year, a discount renewal is offered for a 1 year extension. *
* offer valid for 30 days after end of license. Discount price is subject to change.

Included In

TMS ALL-ACCESS

TMS iCL

Tips and Frequently Asked Questions

Supported Platforms and Operating Systems

Adding an UIToolBarItem to the toolbar of an UITableView in iCL

Fixing the FMX TWebBrowser issue on iOS 9

How to verify if TouchID is available on the device

Initializing controls on multiple forms

Printing a PDF File

Merge multiple PDF documents with TMSFMXNativePDFLib

How to style the UITableView

Add a custom pin image annotation to the TTMSFMXNativeMKMapView

Printing the contents of an UIWebView

Mixing FireMonkey controls and TMS iCL controls

Block Animations

Zooming to fit all annotations in MapView

When deploying to the device, the following error appears: [DCC Error] E2597 ld: file not found: /System/Library/Frameworks/...

TMS iCL

Compatibility

Licensing

Included In

Tags

Bookmarks