unit TMS.MI.StatisticsSample;

interface
  procedure InitializeProfiling;
  procedure StartProfiling;
  procedure StopProfiling;
  procedure ResetStatistics;
  procedure SaveToFile(const AFileName: String);

implementation

uses
  Classes, SysUtils, TMS.MI.Access, TMS.MI.Memory, TMS.MI.UnitNameFilter, TMS.MI.Core;

var
  GStatistics: TTMSMIMemoryStatistics;
  GFilter: TTMSMIUnitNameFilter;

procedure InitializeProfiling;
begin
  // initialize once (it's an example)
  if GStatistics = nil then begin
    // create statistics. attaches to the profiler by itself.
    GStatistics := TTMSMIMemoryStatistics.Create;
    // create a filter, configure and attach it
    GFilter := TTMSMIUnitNameFilter.Create;
    GFilter.Add('*StdCtrls');
    GFilter.Active := True;
    MemoryProfiler.Attach(GFilter);
    // set some options
    MemoryProfiler.Callstacks := [];
    MemoryProfiler.DefaultFilter.TraceTypes := [mtObject];
  end;
end;

procedure StartProfiling;
begin
  MemoryProfiler.Active := True;
end;

procedure StopProfiling;
begin
  MemoryProfiler.Active := False;
end;

procedure ResetStatistics;
begin
  if GStatistics <> nil then
    GStatistics.ResetItems;
end;

procedure SaveToFile(const AFileName: String);
var
  LStream: TStreamWriter;
  i: Integer;
  LItem: PTMSMIMemoryStatisticItem;
  LLine: String;
begin
  if Assigned(GStatistics) then begin
    // disable profiling for this method
    MemoryProfiler.SuspendMethod;
    // stream will be freed when done
    TObjectGuard.Guard(LStream, TStreamWriter.Create(AFileName));
    // dump the statistics
    for i := 0 to GStatistics.Count -1 do begin
      LItem := GStatistics.Items[i];
      LLine := LItem.TypeName + ' Live: ' + IntToStr(LItem.LiveCount)
        + ' +: ' + IntToStr(LItem.Created) + ' -: ' + IntToStr(LItem.Destroyed) + #13#10;
      LStream.Write(LLine);
    end;
  end;
end;

initialization

finalization
  FreeAndNil(GStatistics);
  FreeAndNil(GFilter);

end.